5 次方程式の短い解の公式 B   with  Mathematica14 .0

ClearAll["`*"];

このファイル(formulaB.nb)では「Solving Quintics and Septics by Radicals(Monammed A.Faggal, Daniel Lazard共著)」（以下【原論文】と略記)で示された「7次方程式の解の公式」と類似の方法で導いた「5次方程式の解の公式(formulaB)」の説明をします．ただ formulaB の方は，数値計算も併用しないと厳密解も求まりません．それが【原論文】の著者の方に採用されなかった理由だと思います．

(Subscript[a, 1])と a1 など添え字の大きさのみ違う変数は同じ変数を表すものとします．原則として text の中では読みやすいように (Subscript[a, 1]) を使い，input 文の中では a1 を使います .) また，原則として，抽象的な関数は 大文字で，それを具体化した関数は小文字で表すとします．(これは【原論文】でも同じやり方です.)また変数に関しては具体的な数値には $a の様に 「$」を付けて区別する事もあります．そして Global変数は「$」を付けることが多いです．

このファイルは Mathematica 14.0 で作成されています．コマンドの簡単な説明は入れていますが，詳しい説明は Google してください．Wolfram のサイトで詳しい説明を例題付きで読むことができます．また原論文は Maple で書かれています．したがって，残念ながら，グレブナー基底に関しては再現できないこともありました．

Mathematica  をお持ちの方は 「ノートブックを評価」(15秒程度) して頂ければ　 対話的 （interactive） に読むことができて，分かりやすいと思います． お持ちでない方は  PDF  をご覧になってくれても良いのですが，PDFは文の体裁がかなり崩れ,プログラムは右端が切れてしまいます （ここは是非WolframとAdobeに頑張ってほしい点です)．しかし，無料の  Wolfram  Player  を使えば  ，元の体裁のままノートブックを読むことができるのでお勧めです．

以下，§2までは 「FormulaA . nb」 とほとんど同じです．

§1. (Subscript[F, 10])について

既約でmonicな有理数係数の5次の整式を f=(x^5)+(Subscript[a, 1])(x^4)+(Subscript[a, 2])(x^3)+(Subscript[a, 3])(x^2)+(Subscript[a, 4])x+(Subscript[a, 5]) , f=0 の解を (Subscript[x, 0]), (Subscript[x, 1]),(Subscript[x, 2]) ,(Subscript[x, 3]),(Subscript[x, 4 ])と置きます． 
k=0,1,2,3,4に対し「σ:(Subscript[x, k])→(Subscript[x, k+1]),τ: (Subscript[x, k])→ (Subscript[x, 3k]) 」（添え数字はMod5) とおくと,(Subscript[巡回群C, 5])=<σ>, 2(Subscript[面体群D, 5])=<σ,(τ^2)>, (Subscript[Frobenius群F, 20])=<σ,τ>で，位数はそれぞれ 5,10,20です．そして fのガロア群をGalとすると,fが可解の時，Galは上の3つのいずれかです．（σ,τ の定義は，私の以前のファイルとは異なりますが，以前の定義と共役です.)

{(Subscript[x, 0,])(Subscript[x, 1]),(Subscript[x, 2]),(Subscript[x, 3]),(Subscript[x, 4])}のうち異なる2個をとりその和を作ります．その集合を Y={(Subscript[y, 1]),(Subscript[y, 2])...,(Subscript[y, 10])} と置きます．

Y=Plus@@@Subsets[{x0,x1,x2,x3,x4},{2}]

「F10=(x-(Subscript[y, 1]))(x-(Subscript[y, 2]))⋯(x-(Subscript[y, 10]))」と定義します．

F10=Product[x-Y[[k]],{k,1,10}]

これは vars={(Subscript[x, 0]),(Subscript[x, 1]),⋯,(Subscript[x, 4])} の対称式なので ,vars の基本対称式 (Subscript[s, k])で表されます．更に「解と係数の関係」より (Subscript[a, 1]),(Subscript[a, 2]),⋯,(Subscript[a, 5]) で表せます．

(RefLink[SymmetricReduction, paclet:ref/SymmetricReduction])[f,{(Subscript[x, 1]),…,(Subscript[x, n])}] 
(Subscript[x, 1]),…,(Subscript[x, n])において f==p+q であるような多項式のペア{p,q}を与える．ただし，p は対称な部分であり q は剰余である．

(RefLink[SymmetricReduction, paclet:ref/SymmetricReduction])[f,{(Subscript[x, 1]),…,(Subscript[x, n])},{(Subscript[s, 1]),…,(Subscript[s, n])}]
p における初等対称式を (Subscript[s, 1]),…,(Subscript[s, n])で置き換えたペア{p,q}を与える．

vars={x4,x3,x2,x1,x0};
F10=SymmetricReduction[F10,vars,{-a1,a2,-a3,a4,-a5}][[1]]//Collect[#,x]&

すなわち

(Subscript[F, 10])=(Underscript[Π, 0≤i<j≤4]){[x-((Subscript[x, i])+(Subscript[x, j]))}=(x^10)+4 (Subscript[a, 1]) (x^9) +(6 (Subscript[a, 1]^2)+3 (Subscript[a, 2]))(x^8) +(4 (Subscript[a, 1]^3)+9 (Subscript[a, 1]) (Subscript[a, 2])+(Subscript[a, 3]))(x^7) +((Subscript[a, 1]^4)+9 (Subscript[a, 1]^2) (Subscript[a, 2])+3 (Subscript[a, 2]^2)+4 (Subscript[a, 1]) (Subscript[a, 3])-3 (Subscript[a, 4]))(x^6) +(3 (Subscript[a, 1]^3) (Subscript[a, 2])+6 (Subscript[a, 1]) (Subscript[a, 2]^2)+5 (Subscript[a, 1]^2) (Subscript[a, 3])+2 (Subscript[a, 2]) (Subscript[a, 3])-5 (Subscript[a, 1]) (Subscript[a, 4])-11 (Subscript[a, 5]))(x^5) +(3 (Subscript[a, 1]^2) (Subscript[a, 2]^2)+(Subscript[a, 2]^3)+2 (Subscript[a, 1]^3) (Subscript[a, 3])+6 (Subscript[a, 1]) (Subscript[a, 2]) (Subscript[a, 3])-(Subscript[a, 3]^2)-2 (Subscript[a, 1]^2) (Subscript[a, 4])-2 (Subscript[a, 2]) (Subscript[a, 4])-22 (Subscript[a, 1]) (Subscript[a, 5]))(x^4) +((Subscript[a, 1]) (Subscript[a, 2]^3)+4 (Subscript[a, 1]^2) (Subscript[a, 2]) (Subscript[a, 3])+(Subscript[a, 2]^2) (Subscript[a, 3])-4 (Subscript[a, 3]) (Subscript[a, 4])-16 (Subscript[a, 1]^2) (Subscript[a, 5])-4 (Subscript[a, 2]) (Subscript[a, 5]))(x^3) +(2 (Subscript[a, 1]) (Subscript[a, 2]^2) (Subscript[a, 3])+(Subscript[a, 1]^2) (Subscript[a, 3]^2)-(Subscript[a, 2]) (Subscript[a, 3]^2)+(Subscript[a, 1]^2) (Subscript[a, 2]) (Subscript[a, 4])+(Subscript[a, 2]^2) (Subscript[a, 4])-3 (Subscript[a, 1]) (Subscript[a, 3]) (Subscript[a, 4])-4 (Subscript[a, 4]^2)-4 (Subscript[a, 1]^3) (Subscript[a, 5])-9 (Subscript[a, 1]) (Subscript[a, 2]) (Subscript[a, 5])+7 (Subscript[a, 3]) (Subscript[a, 5]))(x^2) +((Subscript[a, 1]) (Subscript[a, 2]) (Subscript[a, 3]^2)-(Subscript[a, 3]^3)+(Subscript[a, 1]) (Subscript[a, 2]^2) (Subscript[a, 4])-4 (Subscript[a, 1]) (Subscript[a, 4]^2)-4 (Subscript[a, 1]^2) (Subscript[a, 2]) (Subscript[a, 5])-(Subscript[a, 2]^2) (Subscript[a, 5])+4 (Subscript[a, 1]) (Subscript[a, 3]) (Subscript[a, 5])+4 (Subscript[a, 4]) (Subscript[a, 5]))x +(Subscript[a, 1]) (Subscript[a, 2]) (Subscript[a, 3]) (Subscript[a, 4])-(Subscript[a, 3]^2) (Subscript[a, 4])-(Subscript[a, 1]^2) (Subscript[a, 4]^2)-(Subscript[a, 1]) (Subscript[a, 2]^2) (Subscript[a, 5])+(Subscript[a, 2]) (Subscript[a, 3]) (Subscript[a, 5])+2 (Subscript[a, 1]) (Subscript[a, 4]) (Subscript[a, 5])-(Subscript[a, 5]^2)

【コメント】原論文では，終結式 (resultant) を使って導いています .

§2. (Subscript[F, 1]), (Subscript[F, 2])について

σ によるYの軌道分解は 次の (Subscript[O, 1]),(Subscript[O, 2])の二つしかありません．(Mod5 で考えると，(Subscript[O, 1])は添え数字の差が1, (Subscript[O, 2])は差が2)

O1=Table[Total[vars[[Sort[Mod[{0,1}+k,5]]+1]]],{k,0,4}];
O2=Table[Total[vars[[Sort[Mod[{0,2}+k,5]]+1]]],{k,0,4}];
Column[{"(Subscript[O, 1]):"<>ToString[O1],"(Subscript[O, 2]):"<>ToString[O2]}]

(Subscript[O, 1]),(Subscript[O, 2])の要素を解に持つ5次の整式をそれぞれ (Subscript[F, 1]),(Subscript[F, 2 ])と置きます．

F1=Product[(x-O1[[k]]),{k,1,5}]
F2=Product[(x-O2[[k]]),{k,1,5}]

(Subscript[F, 1]),(Subscript[F, 2])はσ ,(τ^2)で変わらず,τによって (Subscript[F, 1])⟷(Subscript[F, 2]) と移ります．また 「f=0」の判別式を D とおくと,(Sqrt[D]) はσ,(τ^2)で変わらず,τによって (Sqrt[D])⟷-(Sqrt[D]) と移ります．(Subscript[故にF, 1]),(Subscript[F, 2])の係数は Q((Sqrt[D]))に入ります．また「5次の整式の根が1つの軌道を形成する場合、その整式は既約多項式または(((x-α))^5)となる」ので，Gal=(Subscript[F, 10])(Subscript[またはC, 5])のとき，(Subscript[F, 1]),(Subscript[F, 2])は共に「Q上既約な5次式」となります．Gal=(Subscript[F, 20])のとき，(Subscript[F, 10])はQ上既約ですが，Q((Sqrt[D]))上では (Subscript[F, 10])=(Subscript[F, 1])(Subscript[F, 2])と 因数分解されます．

【例1】f=4+10 x-(x^2)-6 (x^3)+(x^5)(Gal=(Subscript[F, 10]))

f=4+10 x-(x^2)-6 (x^3)+(x^5);
f10 = F10 /. AssociationThread[{a1, a2, a3, a4, a5} -> Reverse@CoefficientList[f, x, 5]]
d=Sqrt[Discriminant[f,x]](*d=(Sqrt[D])*)
Factor[f10]

(Subscript[f, 10])(Subscript[はQ上でf, 1]),(Subscript[f, 2])に因数分解できました．

【例2】f=12-6 x+12 (x^2)-9 (x^3)+(x^5)(Gal=(Subscript[F, 20]))

f=5+5 x-5 (x^3)+(x^5)
f10 = F10 /. AssociationThread[{a1, a2, a3, a4, a5} -> Reverse@CoefficientList[f, x, 5]]
Factor[f10];
d=Sqrt[Discriminant[f,x]](*d=(Sqrt[D])*)
$f10=Factor[f10,Extension->d]
f1=FactorList[$f10,Extension->d][[3,1]]*(-1/2)//Expand
f2=FactorList[$f10,Extension->d][[4,1]]*(1/2)//Expand

(Subscript[f, 10])はQ上既約ですが，Q((Sqrt[D]))(Subscript[上ではf, 1]),(Subscript[f, 2])に因数分解できました．

f1, f2を見つけるプログラム findF12 は次の様に作れます．出力は{f1,f2}で，$f1,$f2 は f1,f2のGlobal変数です．

findF12[f_]:=Module[{factors,pos},
Clear[a1,a2,a3,a4,a5];
$f10 = F10 /. AssociationThread[{a1, a2, a3, a4, a5} -> Reverse@CoefficientList[f, x, 5]]; 
factors=FactorList[$f10,Extension->Sqrt[Discriminant[f,x]]];
 pos=Position[Exponent[factors, x], 5][[All,1]];
{$f1,$f2}=Expand[#/Coefficient[#,x,5]]&/@factors[[All,1]][[pos]];
If[$f1==x^5,{$f1,$f2}={$f2,$f1}];
Return[{$f1,$f2}]
]

(*例*)findF12[5+5 x-5 (x^3)+(x^5)]

$f1

Gal=(Subscript[F, 20]) のとき，f1とf2は (Sqrt[D]) の係数の符号のみ異なります．したがって (Subscript[f, 1])+(Subscript[f, 2]) ,(Sqrt[D])((Subscript[f, 1])-(Subscript[f, 2]))の係数は Qに含まれます.

$f1+$f2
Sqrt[5]($f1-$f2)//Expand

§3 . G1,G2 の定義

ζ を1の虚数5乗根とするとき，Lagrange  (Subscript[分解式は次のr, 0])~(Subscript[r, 4])になります．(原論文では Fourier transform と呼んでいます.)

Clear[x0,x1,x2,x3,x4]
r0=x0+ x1+ x2+ x3 + x4 ;
r1=x0+ζ x1+ ζ^2 x2 +ζ^3 x3 +ζ^4 x4;
r2=x0+ζ^2 x1+ ζ^4 x2 +ζ x3 +ζ^3 x4;
r3=x0+ζ^3 x1+ ζ x2 +ζ^4 x3 +ζ^2 x4;
r4=x0+ζ^4 x1+ ζ^3 x2 +ζ^2 x3 +ζ x4;

σ,τ によって (Subscript[r, k]) は次の様に移ります．

「σ: (Subscript[r, 0])→(Subscript[r, 0]),(Subscript[r, 1])→(ζ^4)(Subscript[r, 1]), (Subscript[r, 2])→(ζ^3)(Subscript[r, 2]),(Subscript[r, 3])→(ζ^2)(Subscript[r, 3]),(Subscript[r, 4])→(Subscript[ζr, 4])」,「τ:(Subscript[r, k])→(Subscript[r, 2k]), (τ^2):(Subscript[r, k])→(Subscript[r, 4k])」

ここからは 「FormulaA.nb」 と異なります．「u=(Subscript[r, 1])+(Subscript[r, 4]), v=(Subscript[r, 2])+(Subscript[r, 3])」とおくと u(Overscript[→, τ])v,v(Overscript[→, τ])u, また　u,v ((はτ)^2) で不変です．さらに u,v の (Subscript[σによる軌道を解と持つ5次の整式をそれぞれG, 1]),(Subscript[G, 2]) と置きます．即ち,

(Subscript[G, 1])=(x-u)(x-σ(u))⋯(x-(σ^4)(u))
(Subscript[G, 2])=(x-v)(x-σ(v))⋯(x-(σ^4)(v))

具体的に表し 「1+ζ+  (ζ^2)+(ζ^3)+(ζ^4)=0」を使って変形します．

Clear[r1,r2,r3,r4,ζ]

G1=(x-(r1+r4))(x-((ζ^4)r1+ζ r4))(x-((ζ^3)r1+(ζ^2)r4))(x-((ζ^2)r1+(ζ^3)r4))(x-(ζ r1+(ζ^4)r4));
G2=(x-(r2+r3))(x-((ζ^3)r2+(ζ^2) r3))(x-(ζ r2+(ζ^4)r3))(x-((ζ^4)r2+ζ r3))(x-((ζ^2) r2+(ζ^3)r3));

G1=PolynomialMod[Collect[Expand[G1],x],Cyclotomic[5,ζ]]
G2=PolynomialMod[Collect[Expand[G2],x],Cyclotomic[5,ζ]]

即ち 「u=(Subscript[r, 1])+(Subscript[r, 4]), v=(Subscript[r, 2])+(Subscript[r, 3])」とおくと
   ({{{, ({{(Subscript[G, 1])=(x-u)(x-σ(u))⋯(x-(σ^4)(u))=(x^5)-5 (Subscript[r, 1]) (Subscript[r, 4]) (x^3)+5 ((Subscript[r, 1])^2) ((Subscript[r, 4])^2) x-((Subscript[r, 1])^5)-((Subscript[r, 4])^5), □}, {(Subscript[G, 2])=(x-v)(x-σ(v))⋯(x-(σ^4)(v))=(x^5)-5 (Subscript[r, 2]) (Subscript[r, 3]) (x^3)+5 ((Subscript[r, 2])^2) ((Subscript[r, 3])^2) x-((Subscript[r, 2])^5)-((Subscript[r, 3])^5), □}})}})

従って

(*)(Subscript[G, 1]),(Subscript[G, 2]) の (5-k)次の係数をそれぞれ (Subscript[b, k]),(Subscript[c, k])(1≤k≤5)とおくと，(Subscript[b, 1])=(Subscript[c, 1])=(Subscript[b, 3])=(Subscript[c, 3])=0
  ({{{, ({{((Subscript[r, 1])^5)+((Subscript[r, 4])^5)=-(Subscript[b, 5]), □}, {(Subscript[r, 1]) (Subscript[r, 4])=-((Subscript[b, 2])/5) , □}})}})   かつ　({{{, ({{((Subscript[r, 2])^5)+((Subscript[r, 3])^5)=-(Subscript[c, 5]), □}, {(Subscript[r, 2]) (Subscript[r, 3])=-((Subscript[c, 2])/5) , □}})}})

故に , ((Subscript[r, 1])^5)と ((Subscript[r, 4])^(5 ))は次の 「R(x)=0」 の2解となります． ((Subscript[r, 2])^5)と ((Subscript[r, 3])^(5  ))は, (Subscript[b, 2]),(Subscript[b, 5])を それぞれ (Subscript[c, 2]),(Subscript[c, 5 ])で置き換えた方程式の解となります．

R[b2_,b5_]:=x^2+ b5 x+(-b2/5)^5  (*評価してください*)

後は (Subscript[G, 1]),(Subscript[G, 2]) の具体的な形を，何らかの方法で求めることができれば，解の公式が得られます．

§4  g1, g2  を求める

(公式としてのG1, G2を具体化した関数をg1, g2とします．)

以下のセクションで 「f=(x^5)+ (Subscript[a, 2])(x^3)+(Subscript[a, 3])(x^2)+(Subscript[a, 4])x+(Subscript[a, 5]) ((Subscript[a, 1])=0)」と仮定します．

§4-1. 補題

次の補題が必要になります

【補題1】(Subscript[r, 1])+(Subscript[r, 4])-((Subscript[r, 2])+(Subscript[r, 3]))=(Sqrt[5])((Subscript[x, 1])+(Subscript[x, 4])-((Subscript[x, 2])+(Subscript[x, 3])))

(注1) 上の関係式をσ で移した式も成り立ちます．例えば σ で移すと，

((ζ^4) (Subscript[r, 1])+ζ (Subscript[r, 4]))-((ζ^3)(Subscript[r, 2])+(ζ^2)(Subscript[r, 3]))=(Sqrt[5])((Subscript[x, 2])+(Subscript[x, 0])-((Subscript[x, 3])+(Subscript[x, 4])))

(注2){(Subscript[r, 1]),(Subscript[r, 4])}と{(Subscript[r, 2]),(Subscript[r, 3])} の2組に分ける時のみ上のような関係が成り立ちます.例えば{(Subscript[r, 1]),(Subscript[r, 3])}と{(Subscript[r, 2]),(Subscript[r, 4])}の場合は成り立ちません.

【補題2】(Subscript[r, 1])+(Subscript[r, 2])+(Subscript[r, 3])+(Subscript[r, 4])=5(Subscript[x, 0])

(注) 上の関係式をσ で移した式も成り立ちます．例えば (σ^(-1)) で移すと「ζ (Subscript[r, 1])+(ζ^2)(Subscript[r, 2])+(ζ^3)(Subscript[r, 3])+(ζ^4)(Subscript[r, 4])=5(Subscript[x, 4])」となります．

【補題3】(Subscript[s, 1]),(Subscript[s, 2])をそれぞれ (Subscript[f, 1]),(Subscript[f, 2])の解とします．このとき (Subscript[s, 1])と (Subscript[s, 2]) (Subscript[が共通のx, k])を含まない⟺f(-(Subscript[s, 1])-(Subscript[s, 2]))=0

【1の証明】単純計算で,(Subscript[r, 1])+(Subscript[r, 4])-((Subscript[r, 2])+(Subscript[r, 3]))=(ζ+(ζ^4)-(ζ^2)-(ζ^3))((Subscript[x, 1])+(Subscript[x, 4])-(Subscript[x, 2])-(Subscript[x, 3])) 
ここで 「 ζ = Cos[2/5 Pi] + I  Sin[2/5  Pi] 」とすると「ζ+(ζ^4)-(ζ^2)-(ζ^3) = (Sqrt[5]) 」です(有名事実)．（注2）に関しては1つずつチェックすればOKと思われますが，実は私も全てはチェックしていません.(^^;)

【2の証明】「1+ζ+(ζ^2)+(ζ^3)+(ζ^4)=0」だから, (Subscript[r, i]) の定義式の両辺を加えて,(Subscript[r, 0])+(Subscript[r, 1])+(Subscript[r, 2])+(Subscript[r, 3])+(Subscript[r, 4])=5(Subscript[x, 0]) . さらに仮定より (Subscript[a, 1])=0 なので , (Subscript[r, 0])=0.

【3の証明】(Subscript[F, 1])の解は{(Subscript[x, 3])+(Subscript[x, 4]),(Subscript[x, 2])+(Subscript[x, 3]),(Subscript[x, 1])+(Subscript[x, 2]),(Subscript[x, 0])+(Subscript[x, 1]),(Subscript[x, 0])+(Subscript[x, 4])},(Subscript[F, 2])の解は({{{(Subscript[x, 2])+(Subscript[x, 4]),(Subscript[x, 1])+(Subscript[x, 3]),(Subscript[x, 0])+(Subscript[x, 2]),(Subscript[x, 1])+(Subscript[x, 4]),(Subscript[x, 0])+(Subscript[x, 3])}}})です．例えば 「(Subscript[s, 1])=(Subscript[x, 3])+(Subscript[x, 4]), (Subscript[s, 2])=(Subscript[x, 0])+(Subscript[x, 2])」  とすると，(Subscript[s, 1])と (Subscript[s, 2])は共通項がないので 「f(-(Subscript[s, 1])-(Subscript[s, 2]))=f(-(Subscript[x, 3])-(Subscript[x, 4])-(Subscript[x, 0])-(Subscript[x, 2]))=f((Subscript[x, 1]))=0」です．一方，「(Subscript[s, 1])=(Subscript[x, 3])+(Subscript[x, 4]), (Subscript[s, 2])=(Subscript[x, 1])+(Subscript[x, 3])」  とすると，(Subscript[s, 1])と (Subscript[s, 2])(Subscript[は共通項x, 3])を持ち「f(-(Subscript[s, 1])-(Subscript[s, 2]))=f(-(Subscript[x, 1])-2(Subscript[x, 3])-(Subscript[x, 4]))」です.もしこの値が0になったとすると (-(Subscript[x, 1])-2(Subscript[x, 3])-(Subscript[x, 4]))は fの解のいずれかです．仮に「-(Subscript[x, 1])-2(Subscript[x, 3])-(Subscript[x, 4])=(Subscript[x, 2])」となったとすると「(Subscript[x, 1])+(Subscript[x, 2])+2(Subscript[x, 3])+(Subscript[x, 4])=0」です．この式を σで移した式も成り立つので「(Subscript[x, 2])+(Subscript[x, 3])+2(Subscript[x, 4])+(Subscript[x, 0])=0,⋯,(Subscript[x, 0])+(Subscript[x, 1])+2(Subscript[x, 2])+(Subscript[x, 3])=0」も成り立ちます．これは 「(Subscript[x, 0])=⋯=(Subscript[x, 5])」を意味するので矛盾します．

§4-2. 終結式とGCD(最大公約因子)を使った求め方

(#1)「(Subscript[x, 1])+(Subscript[x, 4]),(Subscript[x, 2])+(Subscript[x, 3]), (Subscript[r, 1])+(Subscript[r, 4]) ,(Subscript[r, 2])+(Subscript[r, 3]), を (σ^i)(iはある0以上の整数) で移した式を各々 (Subscript[s, 1]),(Subscript[s, 2]) ,(Subscript[t, 1]),(Subscript[t, 2])」 とすると，上の補題から以下の式を満たす f の解x が存在します.

(#2)({{{, ({{(Subscript[s, 1])+(Subscript[s, 2])+x=0, (ア) }, {(Subscript[t, 1])+(Subscript[t, 2])=5x, (イ)}, {(Subscript[t, 1])-(Subscript[t, 2])=(Sqrt[5])((Subscript[s, 1])-(Subscript[s, 2])), (ウ)}, {f(x)=0, (エ)}, {(Subscript[f, 1])((Subscript[s, 1]))=0, (オ)}, {(Subscript[f, 2])((Subscript[s, 2]))=0, (カ)}})}})

「(#1) → (#2) 」は明らかですが，逆に (#2)が成り立てば (#1)が成り立ちそうです．(以下は厳密な証明ではありません)というのも，まず(オ)と(カ)から (Subscript[s, 1])(Subscript[とs, 2])は (Subscript[x, i])+(Subscript[x, j])(i≠j) の形です．さらに(ア)(エ)より「f(-(Subscript[s, 1])-(Subscript[s, 2]))=0 」なので (Subscript[s, 1])と (Subscript[s, 2])は共通項 (Subscript[x, k])を持ちません．さらに(イ)(ウ)より {(Subscript[s, 1]),(Subscript[s, 2]),(Subscript[t, 1]),(Subscript[t, 2])}={(σ^i)((Subscript[x, 1])+(Subscript[x, 4])),(σ^i)((Subscript[x, 2])+(Subscript[x, 3])), (σ^i)((Subscript[r, 1])+(Subscript[r, 4])) ,(σ^i)((Subscript[r, 2])+(Subscript[r, 3]))}となります．

まず（ア)(イ)(ウ)から x,(Subscript[s, 1,])(Subscript[s, 2])を消去すると
               　　({{{, ({{x=((Subscript[t, 1])+(Subscript[t, 2]))/5, □}, {(Subscript[s, 1])=-((Subscript[t, 1])+(Subscript[t, 2]))/10+(Sqrt[5])((Subscript[t, 1])-(Subscript[t, 2]))/10, □}, {(Subscript[s, 2])=-((Subscript[t, 1])+(Subscript[t, 2]))/10-(Sqrt[5])((Subscript[t, 1])-(Subscript[t, 2]))/10, □}})}})

これらを(エ)~(カ)へ代入した後， (Subscript[t, 1])の関係式（=(Subscript[G, 1]))(Subscript[とt, 2])の関係式(=(Subscript[G, 2]))を求めることができますが，対称性より「(Subscript[f, 1])((Subscript[s, 1]))±(Subscript[f, 2])((Subscript[s, 2]))」を用いた方が効率的です．

「(Subscript[f, 1])((Subscript[s, 1]))=(Subscript[f, 2])((Subscript[s, 2]))=0」⇔「(Subscript[f, 1])((Subscript[s, 1]))+(Subscript[f, 2])((Subscript[s, 2]))=0かつ (Subscript[f, 1])((Subscript[s, 1]))-(Subscript[f, 2])((Subscript[s, 2]))=0」　ですから， (エ)(オ)(カ)より

(#3) 「 f((((Subscript[t, 1])+(Subscript[t, 2]))/5))=0」∧「(Subscript[f, 1])((Subscript[s, 1]))+(Subscript[f, 2])((Subscript[s, 2]))=0」∧「(Subscript[f, 1])((Subscript[s, 1]))-(Subscript[f, 2])((Subscript[s, 2]))=0」

この連立方程式を満たす (Subscript[t, 1])の条件式が (Subscript[G, 1]) で，(Subscript[t, 2])の条件式が (Subscript[G, 2])です．よって ，終結式と最大公約因数(GCD)を用いて求まります．

(#4) 終結式と最大公約因数(GCD)を用いた求め方
f((((Subscript[t, 1])+(Subscript[t, 2]))/5))と「(Subscript[f, 1])((Subscript[s, 1]))+(Subscript[f, 2])((Subscript[s, 2]))」の (Subscript[t, 2])に関する終結式 をR1((Subscript[t, 1])),
f((((Subscript[t, 1])+(Subscript[t, 2]))/5))と「(Subscript[f, 1])((Subscript[s, 1]))-(Subscript[f, 2])((Subscript[s, 2]))」の (Subscript[t, 2])に関する終結式 をR2((Subscript[t, 1])) 
とすると，「G1((Subscript[t, 1]))=DCG(R1((Subscript[t, 1])),R2((Subscript[t, 1])))」．G2 は R1,R2を 「(Subscript[t, 1])に関する終結式」として求め 「G2((Subscript[t, 2]))=DCG(R1((Subscript[t, 2])),R2((Subscript[t, 2])))」

例.   f=12-6 x+12 (x^2)-9 (x^3)+(x^5)

まずは コマンド  findF12  を使って  (Subscript[f, 1])(x), (Subscript[f, 2])(x)を求めます．

Clear[f,f1,f2,g1,g2]
f[x_]=12-6 x+12 (x^2)-9 (x^3)+(x^5)
f12=findF12[f[x]];
f1[x_]=f12[[1]]
f2[x_]=f12[[2]]

(#4) に従い，(Subscript[次の様にg, 1]) (x) が求まります．（最後の行は  monic  に直して，変数を  t1 → x  に変えているだけです．)

R1=Resultant[f[(t1+t2)/5],f1[-(t1+t2)/10+Sqrt[5](t1-t2)/10]+f2[-(t1+t2)/10-Sqrt[5](t1-t2)/10],t2];
R2=Resultant[f[(t1+t2)/5],f1[-(t1+t2)/10+Sqrt[5](t1-t2)/10]-f2[-(t1+t2)/10-Sqrt[5](t1-t2)/10],t2];
gcd1=PolynomialGCD[R1,R2,Extension->Automatic]
g1[x_]=Expand[gcd1/Coefficient[gcd1,t1,5]]/.{t1->x}//Collect[#,x]&

同様に (Subscript[g, 2])  (x)  が求まります．

Timing[R1=Resultant[f[(t1+t2)/5],f1[-(t1+t2)/10+Sqrt[5](t1-t2)/10]+f2[-(t1+t2)/10-Sqrt[5](t1-t2)/10],t1];
R2=Resultant[f[(t1+t2)/5],f1[-(t1+t2)/10+Sqrt[5](t1-t2)/10]-f2[-(t1+t2)/10-Sqrt[5](t1-t2)/10],t1];
gcd2=PolynomialGCD[R1,R2,Extension->Automatic];
g2[x_]=Expand[gcd2/Coefficient[gcd2,t2,5]]/.{t2->x}//Collect[#,x]&]

(Subscript[g, 1]), (Subscript[g, 2])を両方求めるには  約  0.3 秒  かかりましたが，次のグレブナー基底を使うともっと速く求まります．

§4-3. グレブナー基底を使った求め方(原論文にはありません)

(Subscript[g, 1])を求めるには(#3) の生成するイデアルのグレブナー基底を  (Subscript[t, 2])  を消去するモードで実行します．

gb=GroebnerBasis[{f[(t1+t2)/5],f1[-(t1+t2)/10+Sqrt[5](t1-t2)/10]+f2[-(t1+t2)/10-Sqrt[5](t1-t2)/10],(f1[-(t1+t2)/10+Sqrt[5](t1-t2)/10]-f2[-(t1+t2)/10-Sqrt[5](t1-t2)/10])},{t1},{t2}]
Expand[#/Coefficient[#,t1,5]]&[gb[[1]]]/.{t1->x}//Collect[#,x]&

(Subscript[g, 2])を求めるには (#3)  の生成するイデアルのグレブナー基底を   (Subscript[t, 1])  を消去するモードで実行します．

Timing[gb=GroebnerBasis[{f[(t1+t2)/5],f1[-(t1+t2)/10+Sqrt[5](t1-t2)/10]+f2[-(t1+t2)/10-Sqrt[5](t1-t2)/10],(f1[-(t1+t2)/10+Sqrt[5](t1-t2)/10]-f2[-(t1+t2)/10-Sqrt[5](t1-t2)/10])},{t2},{t1}];
Expand[#/Coefficient[#,t2,5]]&[gb[[1]]]/.{t2->x}//Collect[#,x]&]

実行時間は合計で約0.03  秒です．この方が約10倍速いですが，グレブナー基底は時々予測不能の式を出してくるので，少し心配ではあります．実際，7次方程式ではうまくいかない例がありました．(g1={t1}またはg2={t2}となります.)

(#5) グレブナー基底を使った求め方
g1を求めるには，(#3)の生成するイデアルのグレブナー基底を t2 を消去するモードで求める．g2を求めるには， t1 を消去するモードで求める．しかし上手くいかないことも稀にある．

実行時間の差は0.5秒もないので，終結式を使って (Subscript[f, 1]),(Subscript[f, 2]), (Subscript[g, 1]),(Subscript[g, 2]) を求めるプログラムを書きました．

findF12G12[f_] := Module[{factors,pos,s1,s2,R1,R2,gcd1,gcd2,t1,t2},
Clear[a1,a2,a3,a4,a5,s1,s2];
$f10 = F10 /. AssociationThread[{a1, a2, a3, a4, a5} -> Reverse@CoefficientList[f, x, 5]]; 
factors=FactorList[$f10,Extension->Sqrt[Discriminant[f,x]]];
 pos=Position[Exponent[factors, x], 5][[All,1]];
{$f1,$f2}=Expand[#/Coefficient[#,x,5]]&/@factors[[All,1]][[pos]];
  s1=-(t1+t2)/10+Sqrt[5](t1-t2)/10;
  s2=-(t1+t2)/10-Sqrt[5](t1-t2)/10;
R1=Resultant[f/.{x->(t1+t2)/5},($f1/.{x->s1})+($f2/.{x->s2}),t2];
R2=Resultant[f/.{x->(t1+t2)/5},($f1/.{x->s1})-($f2/.{x->s2}),t2];
gcd1=PolynomialGCD[R1,R2,Extension->Automatic];
$g1=Expand[gcd1/Coefficient[gcd1,t1,5]]/.{t1->x}//Collect[#,x]&;
R1=Resultant[f/.{x->(t1+t2)/5},($f1/.{x->s1})+($f2/.{x->s2}),t1];
R2=Resultant[f/.{x->(t1+t2)/5},($f1/.{x->s1})-($f2/.{x->s2}),t1];
gcd2=PolynomialGCD[R1,R2,Extension->Automatic];
$g2=Expand[gcd2/Coefficient[gcd2,t2,5]]/.{t2->x}//Collect[#,x]&;
Return[{$f1,$f2,$g1,$g2}]]

例えば先の例の関数fについて {(Subscript[f, 1]),(Subscript[f, 2]),(Subscript[g, 1]),(Subscript[g, 2])}は次の様に求まります．

findF12G12[f[x]]

§5. fの解を求める

§4で次の式を導きました．

(*)(Subscript[G, 1]),(Subscript[G, 2]) の (5-k)次の係数をそれぞれ (Subscript[b, k]),(Subscript[c, k])(1≤k≤5)とおくと，(Subscript[b, 1])=(Subscript[c, 1])=(Subscript[b, 3])=(Subscript[c, 3])=0
  ({{{, ({{((Subscript[r, 1])^5)+((Subscript[r, 4])^5)=-(Subscript[b, 5]), (1)}, {(Subscript[r, 1]) (Subscript[r, 4])=-((Subscript[b, 2])/5) , (2)}})}})   かつ　({{{, ({{((Subscript[r, 2])^5)+((Subscript[r, 3])^5)=-(Subscript[c, 5]), (3)}, {(Subscript[r, 2]) (Subscript[r, 3])=-((Subscript[c, 2])/5) , (4)}})}})

((Subscript[r, 1])^5)((Subscript[とr, 4])^5)を解とする方程式は次の「R=0」となります．(((Subscript[r, 2])^5)((Subscript[とr, 3])^5)を解とする式は {(Subscript[b, 2]),(Subscript[b, 5])}→{ (Subscript[c, 2]),(Subscript[c, 5])} )

R[b2_,b5_]:=x^2+ b5 x+(-b2/5)^5

fの解を求めるには 上のRの方程式と(2)より (Subscript[r, 1])(Subscript[とr, 4 ])を求めます．次に 再び Rの方程式から {(Subscript[R, 2])(((Subscript[r, 2])^5)), (Subscript[R, 3])(((Subscript[r, 3])^5))} を求めます．ただし Rの方程式の2解のうちどちらが (Subscript[R, 2])なのか分からないので,(3)(4)を満たす {(Subscript[r, 2]),(Subscript[r, 3])} のセットは10通りできます．これらの　{(Subscript[r, 1]),(Subscript[r, 2]),(Subscript[r, 3]),(Subscript[r, 4])}の値から (Subscript[x, 0])~(Subscript[x, 4 ]) の値を求め，fの数値解と比較します．

例で見てみましょう．

【例】f=4+10 x-9 (x^2)-14 (x^3)+(x^5)

Clear[f]
f=4+10 x-9 (x^2)-14 (x^3)+(x^5);

（ア）(Subscript[g, 1]),(Subscript[g, 2 ]),(Subscript[b, k]), (Subscript[c, k])を求めます

{g1,g2}=findF12G12[f][[{3,4}]]

{b2,b3,b4,b5}=CoefficientList[g1,x,4]//Reverse
{c2,c3,c4,c5}=CoefficientList[g2,x,4]//Reverse

（イ） Rの式を使って，(Subscript[R, 1])=((Subscript[r, 1])^5)を求め, (Subscript[r, 1])=((Subscript[R, 1])^(1/5)),(Subscript[r, 1]) (Subscript[r, 2])=-(Subscript[b, 2])/5 を使って (Subscript[r, 1]),(Subscript[r, 4 ])を求めます.

R14=R[b2,b5]//Simplify

{R1,R4}=x/.Solve[R14==0,x]//Simplify

r1=R1^(1/5)//Simplify
r4=-b2/(5r1)//FullSimplify

（ウ）  Rの式を使って，{(Subscript[R, 2])(((Subscript[r, 2])^5)),(Subscript[R, 3])(((Subscript[r, 3])^5))} を求め, (Subscript[r, 2])=((Subscript[R, 2])^(1/5)),(Subscript[r, 3]) (Subscript[r, 4])=-(Subscript[c, 2])/5 を使って (Subscript[r, 2]),(Subscript[r, 3 ])の候補 $r2, $r3 を求めます.

R23=R[c2,c5]//Simplify

{R2,R3}=x/.Solve[R23==0,x]//Simplify

$r2=R2^(1/5)
$r3=-c2/(5$r2)//FullSimplify

（エ）{r2,r3}の正しい式は {$r2,$r3},{ζ $r2,(ζ^4)$r3},⋯,{(ζ^4) $r2,ζ $r3} または  {$r3,$r2},{ζ $r3,(ζ^4)$r2},⋯,{(ζ^4) $r3,ζ $r2}の10組のいずれかです．（これら全てが(3)(4)を満たします)この10組をLagrangeの逆変換に代入して fの解の候補の集合Xsを作ります．

Clear[ζ]
r2s=Join[$r2 ζ^{0,1,2,3,4},$r3 ζ^{0,1,2,3,4}];
r3s=Join[$r3 ζ^{0,4,3,2,1},$r2 ζ^{0,4,3,2,1}];
Xs=Table[1/5{{1,1,1,1,1},ζ^{0,4,3,2,1},ζ^{0,3,1,4,2},ζ^{0,2,4,1,3},ζ^{0,1,2,3,4}}.{0,r1,r2s[[k]],r3s[[k]],r4},{k,1,10}];

（オ）「ζ = Cos(2π/5)+ι sin(2π/5))」 として,  Xsの近似値$Xs と f の数値解 $sol を比較します.

$Xs=Column[Sort/@N[(Xs/.{ζ->Cos[2 Pi/5]+I Sin[2  Pi/5]})]//Chop]
$sol=x/.NSolve[f==0,x]//Sort

二つを比べると $Xs[[9]] が 最も $sol に近いことが分かります．(近いというより，全く一致しています)
故にfの厳密解は Xs[[9]] (即ち{r2,r3}={$r3 (ζ^3),$r2 (ζ^2) }) と分かります．
なお，ζの偏角は 2π/5*m (1≤m≤4)のいずれでも良いですが，違う偏角を選ぶと異なる Xsの要素が $sol と一致します.

X={x0,x1,x2,x3,x4}=Xs[[9]];

(Subscript[x, 0]), (Subscript[x, 1 ])のみ表示します. (ζ の偏角は 2π/5 )

TraditionalForm[x0]
TraditionalForm[x1]

【コメント】 このやり方は (1)~(4)の公式を導くまでは非常にすっきりしているのですが， (Subscript[g, 1]),   (Subscript[g, 2]) だけでは情報量が足りず，最後で数値計算をしないといけないのが，玉に瑕です．一方，7次方程式では (Subscript[g, 1]), (Subscript[g, 2]) だけでほぼ十分な情報が得られて，もう少しちゃんとした解の公式を作る事ができます．