東京医大2017年　入試問題

ClearAll["Global`*"]
A1={a,0};A2={a3,a4};B1={b1,b2};B2={b3,b4};p={x,y};
eqs=A1.B1==3&&A1.B2==4&&A2.B1==5&&A2.B2==7&&A1.p==14&&A2.p==23&&B1.p==22&&B2.p==35;

Exists[{a,a3,a4,b1,b2,b3,b4,x,y},eqs&&(A2-A1).(B1-p)==k1];
Resolve[%,Reals]
Exists[{a,a3,a4,b1,b2,b3,b4,x,y},eqs&&x^2+y^2==k2];
Resolve[%,Reals]

(*1*)
f[x_]:=x^5+ a x^4+b x^3+c x^2;
cons=f'[0]==0∧f[0]==0∧f''[0]<0∧f'[5]==0∧f[5]==0∧f''[5]>0;(*conditions*)
Exists[{a,c},cons];
Resolve[%,Reals]//Simplify
Exists[{a,b,c,p},cons&&f'[p]==0&&f[p]==M&&f''[p]<0&&p≠0];
Resolve[%,Reals]//Simplify

(*2*) ClearAll["Global`*"]
f[x_]=((a x)^(-(b x)^(c x)/3))/.{a->8,b->1/E,c->-Log[2]};
f'[1]

ClearAll[a]

sol=RSolve[{a[n+1]==a[n]Cos[n^2 Pi/3],a[1]==1},a[n],n];
a[n_]=(a[n]/.sol)[[1]]//FullSimplify

(*1*)
a[6]
Sum[a[k],{k,1,6}]

(*2*)
Log[2,Abs[a[70]]]
Sum[a[6k+1],{k,1,Infinity}]

(*3*)
Sum[Sum[a[6k+r],{k,0,Infinity}],{r,1,6}]

ClearAll[f,x]
f[x_]=1/2x+1/8x^3;
F=ImplicitRegion[f[x]<y<2&&x>0,{x,y}];
Show[Plot[{f[x],2},{x,-1,3}],RegionPlot[F]]

(*1*)
RegionMeasure[F]

(*2*) ( InverseFunction は逆関数の枝のうち適当にひとつを選ぶので,出題者の意図した解答と符号が異なる)

ClearAll[f,h,g]
f[x_]=1/2x+1/8x^3;
h[x_]=x^2;
g=Composition[h,InverseFunction[f]];(*g=((((f^(-1))))^2)*)
InverseFunction[g][2]

(*上では (h^(-1))[x]=-(Sqrt[x]) の枝を取っているので符合が異なる! そこで手動で解答する*)

Composition[f,Sqrt[#]&][2]

(*3*)
(*バウムクーヘン分割の利用*)
Integrate[2Pi x (2-f[x]),{x,0,2}]

(*RegionMeasure の利用. 答えは一致するが, ちょっと時間が掛かる*)

ImplicitRegion[2>z>f[Sqrt[x^2+y^2]],{x,y,z}];
RegionMeasure[%]

ContourPlot[(x^2+y^2)^2==x^3-3x y^2, {x,-0.7,1.1},{y,-1,1},PlotPoints->50,Axes->True]