5. これらも一行で解ける

【方程式の解】 正三角形PQRが放物線y = (x^2) に内接し，QRの傾きが(Sqrt[2])の時，１辺の長さを求めよ．(2004 年)  これは Solve でも解ける.

P(p,(p^2)),Q(q,(q^2)),R(r,(r^2))とおくと QRの傾きは q+r. さらに１辺の長さを a とおく．

Exists[{p,q,r},p≠q&&q≠r&&r≠p&&(p-q)^2+(p^2-q^2)^2==(q-r)^2+(q^2-r^2)^2==(r-p)^2+(r^2-p^2)^2==a^2&&r+q==Sqrt[2]&&a>0];
Resolve[%,Reals]

【最大・最小】 (x^3) - 2 (x^2) - 3 x + 4 (-(7/4)≦ x ≦ 3) の最大・最小値を求めよ．(1991 年)

Exists[x,x^3-2x^2-3x+4==k&&-7/4≤x≤3];
Resolve[%,Reals]

【軌跡】 z = (y^2), x = 0 上に動点Qをとる．さらに定点P (2, 0, 1) としたとき，直線PQ と xy平面との交点Rの軌跡を求めよ.(1991 年)

Exists[{t,s},x-2==-2s&&y==-t s&&(t^2-1)s==-1];
Resolve[%,Reals]
ContourPlot[{y==-(1/2) Sqrt[-2 x+x^2],y==1/2 Sqrt[-2 x+x^2]},{x,-3,8},{y,-3,3},Axes->True]

【連立方程式が特定の解を持つ条件】 y = k (x - (x^3)), x = k (y - (y^3)) が第1象限内でy = x上にない交点を持つ正の数kの範囲を求めよ.(1989 年)

Exists[{x,y},y==k(x-x^3)&&x==k (y-y^3)&&x≠y&&k>0&&x>0&&y>0];
Resolve[%,Reals]

【必要十分条件】 「x > 1 かつy > 1」 であることは 「x + y > 2」 となるための[   ] 条件である.(1964 一次)

ForAll[{x,y},Implies[x>1&&y>1,x+y>2]];　Resolve[%]
ForAll[{x,y},Implies[x+y>2,x>1&&y>1]];　Resolve[%]

【最小値】 長さl (l ≧ 1) の線分が その両端をy = (x^2) の上に置いている時，線分の中点Mがx軸に最も近い場合のMの座標を求めよ.(1974 文理)

Exists[{p,q},(p-q)^2+(p^2-q^2)^2==l^2&&y==(p^2+q^2)/2&&l≥1];
Resolve[%,Reals]

【存在条件】 f (x) = (ax^3) + (bx^2) + cx + d が 3条件
(イ) f (-1) = 0,　 (ロ) f (1) = 0,  (ハ)| x | ≦ 1の時 f (x) ≧ 1 - | x |　
をみたすのは，定数a, b, c, dがどのような条件をみたすときか？ (1981 理)

Clear[f,x,a,b,c,d];f[x_]=a x^3+b x^2+c x+d;
ForAll[x,(Abs[x]≤1\[Implies]f[x]≥1-Abs[x])&&f[1]==f[-1]==0];
Resolve[%,Reals]//FullSimplify

【通過領域】 A (((2((t^2)+t+1))/(3 (t+1))), -2),  B ((2/3)t, -2 t)  と定める．t が 0 ≦ t ≦ 1 を動くとき 直線AB の通過領域を求めよ． (1997 文)

(*AB:y=-2t^3+3xt^2-3x となるので*)
Exists[t,y==-2t^3+3 x t^2-3 x&&0≤t≤1];
Resolve[%,Reals]//FullSimplify
RegionPlot[%,{x,-3,4},{y,-4,4}]

【通過領域】 P ((1/2), (1/4)), y = (x^2)上の2点Q (a, (a^2)), R (b, (b^2)) を PQ = PR となるように動かすとき △PQRの重心G (X, Y) の軌跡を求めよ． (2011 理)

Exists[{a,b},(a-1/2)^2+(a^2-1/4)^2==(b-1/2)^2+(b^2-1/4)^2&&X==1/3(a+b+1/2)&&Y==1/3(a^2+b^2+1/4)];
Resolve[%,Reals]//FullSimplify

【通過領域】 A (-1, 1), B (1, -1), P (x, y) (| x | ≦  1) に対し次の (1) または (2) をみたすP の存在範囲を求めよ．
(1) 頂点のx座標の絶対値が1以上の2次関数でA, B, P を通るものが存在する．
(2) A, P, B は一直線上にある (2015 年文）．

Clear[a,p,q,f,x]
f[x_]=a (x-p)^2+q;
Exists[{a,p,q},(1==f[-1]&&-1==f[1]&&Y==f[X]&&-1≤X≤1&&Abs[p]≥1)||Y==-X];
Resolve[%,Reals]//FullSimplify
RegionPlot[%,{X,-1,1},{Y,-1,1},Axes->True]

Vは底面が図の斜線部分，高さがbの柱体になるので volume(V)=((π/4)((a^2)+(c^2))+ac) b

Exists[{a,b,c},a+b+c==1&&a>0&&b>0&&c>0&&(Pi(a^2+c^2)/4+a c)b==k];
Resolve[%,Reals]